OpenMenu
{ OnMenu }
Choice.pamamu
{ OnMenu }
OnMenu
{
    if !aoiMenu ; NaoiMenu
    --
    playerhead
    --
    TeliDatabase
    --
    if pont >= 8 && !aoiPontplus { aoiPontplus = 1 ; aitalkinterval = 300 }
    if san < 0 { BedEnd ; return }
    if TOINT(pont) > 524 {
        if san < 50 { NormalEnd ; return }
        if ((intimacy >= 100) && (intimacy2 >= 100)) { TrueEnd ; return }
        else { HappyEnd ; return }
    }
    --
    if _argv[0] { "\0\s[%(bsus)]\f[name,%(zitai)]\_q\![set,autoscroll,disable]"+_argv[0] }
    else
    {
        if !tea
        { 
            "\0\s[%(bsus)]\f[name,%(zitai)]\_q\![set,autoscroll,disable]\f[size,14]"
            --
            "ボスォタは、高性能ですから!"
            MenuTalk
            if aoiPontplus { "\![*]按回车输入数字可调整说话概率" }
            if RAND(100) > 98 ; GetTama
         }else{
            "\1\s[%(gsus)]\f[name,%(zitai)]\_q\![set,autoscroll,disable]\f[size,14]"
            --
             "璃珈南をあなたに"
             MenuTalk
             if aoiPontplus { "\![*]按回车输入数字可调整说话概率" }
             if RAND(100) > 98 ; GetTama
        }
        --
        \f[size,default]
    }
    --
    "\n"
    --
    if !tea
    { "/
    \_l[127,-]\![*]\q[关于波斯尔泰,AboutBosrc]\n/
    \q[◀  地図散步,OnStartChizuSanpo,地図散步]\_l[296,-]\q[往里面走  ▶,Onsaika,1]\n/
    \_l[60,-]\![*]\q[探访病房,atashi]\_l[157,-]\![*]\q[药房,OnwanNeRoom]\_l[223,-]\![*]\q[打工,Onbaito]\_l[290,-]\![*]\q[新闻,news]\n/
    %(lisL('\_?- - - - - - - - - - - - - - - - - - - -\_?'))\n/
    \q[＊我的信息,uewedio]\_l[129,-]\q[＊存档,OnSaveLoad]\_l[191,-]\q[＊物品箱,mono]\_l[268,-]\q[＊设置,Onsettei]\_l[329,-]\q[＊刷新,susfresh]\n/
    "}else{
    AboutGentEnd
    --
    if !aoiWalusaitu ; "\_q\![set,autoscroll,enable]"+NaoiWalusaitu ;
    else{"/
    \_l[110,-]\![*]\q[关于gent,AboutGent]\_l[268,-]\![*]\q[刚才的话,outalk,查看刚才浏览过的对话]\n/
    \q[◀  返回大厅,Onsaika,0]\_l[130,-]\![*]\q[观察大树,likanandasa]\n/
    \_l[150,-]\![*]\q[记忆整理,TheArk]\n/
    %(lisL('\_?- - - - - - - - - - - - - - - - - - - -\_?'))\n/
    \q[＊我的信息,]\_l[129,-]\q[＊存档,OnSaveLoad]\_l[191,-]\q[＊物品箱,mono]\_l[268,-]\q[＊设置,Onsettei]\_l[329,-]\q[＊刷新,susfresh]/
    "}}
}
Choice.susfresh
{ if !tea ; playerhead+"\1\s[10]\0\s[0]\e" ; else ; playerhead+"\0\s[0]\1\s[20]\e" }
Onsaika
{ tea = reference0 ; OnMenu }
Choice.outalk
{ lastTalk }
//***** --------------------------------------------------------------------------------------------------------------------------------------------
//***** 文本、资源*********************************************
MenuTalk : sequential
{ 
"\![*]"
--
"包裹着黄蕊的花瓣由白变黑，似乎被什么东西污染了一样"
"魈深白花盛开的时期，黄蕊褪成白色，花朵变成黑白相间"
"深白与魈魉共存，一面代表“不存在”，一面代表“存在”"
"璃珈南本是没有颜色，为了在这片天空下具象化……"
"如明镜般观测内心，她可以是棕红，是玉黄，是翠绿……"
"只有心知其义，花语是心之镜子，是现代流行的一种花"
 }
NaoiMenu
{ <<"
\c\0\f[name,%(zitai)]\s[%(bsus+2)]这里是菜单，是放着主要功能的地方，如果觉得自己的信息有错的话，可以点击「我的信息」修改，
\x\s[%(bsus+1)]如果担心故事进度出错了的话，可以点击「我的存档」SL，
\x\s[%(bsus+2)]物品箱里存放着收集到的物品，包括购买的药物，物品可以赠送给波斯尔泰和gent，药品可以维持您自己的状态，
\x\s[%(bsus+3)]注意，自己的精神状态和物品的收集程度都会影响结局的判断，
\x\s[%(bsus+4)]欢迎来到愚女坡。\x\![raise,OnMenu]\e%(aoiMenu = 1)
">> }
NaoiSettei
{ <<"
\c\0\f[name,%(zitai)]\s[%(bsus+2)]设置，在这里可以修改对话框的字体，还有您名字显示的字体，默认是等线，
\x\s[%(bsus+1)]音乐播放器、视频播放器、第三程序均为三个程序的快捷方式，可以自由定义，在路径设置里面修改路径，
\x\s[%(bsus+2)]屏幕亮度中，可调节电脑显示器的亮度，系统最少win7、SSP最好2.6以上、显示器必须支持DDC/CI协议
\x\s[%(bsus+4)]最后一行是今日运势和音乐盒，这两项功能就偷偷地用着，翘咪咪地不出声\x\![raise,Onsettei]\e%(aoiSeittei = 1)
">> }
NaoiWanNe
{ <<"
\c\0\f[name,%(zitai)]这里是药房，用“光玉”买药的地方，此人格中“花瓣”、“玉响”、“辉屑”，统称“光玉”。
\x\s[%(bsus+2)]光玉主要通过打工获取，部分地方也有极小可能获得，
\x\s[%(bsus+1)]用药物稳定情绪是这个人格的主要玩法，通过服用不同的药物可以稳定不同维度的情绪，
\x\s[%(bsus+4)]是否稳定情绪可以打出不同结局，加油吧！\x\![raise,OnwanNeRoom]\e%(aoiWanNe = 1)
">> }

//***** 剧情进展函数----------------------------------------------------------------------------------------------------------------------------------------
//*****gent********************
Choice.AboutGent
{
    if !gentsue { gentsue = 1 ; UserThinkGent[0] }
    elseif gentsue == 1 { gentsue = 2 ; UserThinkGent[1] }
    elseif gentsue == 2 { gentsue = 3 ; UserThinkGent[2] }
    elseif gentsue == 3 { gentsue = 4 ; UserThinkGent[3] }
    else { UserThinkGent[RAND(4)] }
    --
    "\x"+NastoliaGent
}
NastoliaGent
{
"\*\![set,autoscroll,disable]\1\s[%(gsus)]\f[name,%(zitai)]\_q【gent】\_q\b[2]"
--
"\![*]想问我什么？\n\_b[img/%(userimg).png,10,10,--option=use_self_alpha]/
\_l[35,-]\q[你为什么活了下来？,GentQ1]\n/
\_l[35,-]\q[你为什么来到这里？,GentQ2]\n/
\_l[35,-]\q[不久之后你也会离开吗？,GentQ3]\n/
\![*]\q[离开,pamamu]\e"
}
Choice.GentQ1
{ if !aoiGentQ1 { aoiGentQ1 = 1 ; pont++ } Sueia01 }
Choice.GentQ2
{ if !aoiGentQ2 { aoiGentQ2 = 1 ; pont++ } Sueia02 }
Choice.GentQ3
{ if !aoiGentQ3 { aoiGentQ3 = 1 ; pont++ } Sueia03 }
AboutGentEnd
{ if gentsue == 4 && pont >=3 { 
"\1\![bind,脖子,伤痕,1]\![bind,左手,手术线,1]"
"\1\![bind,脖子,伤痕,0]\![bind,左手,绷带,1]"
} }
//*****波斯尔泰********************
Choice.AboutBosrc
{
    if !bosrcsue { bosrcsue = 1 ; UserTellBosrc[0] }
    elseif bosrcsue == 1 { bosrcsue = 2 ; UserTellBosrc[1] }
    elseif bosrcsue == 2 { bosrcsue = 3 ; UserTellBosrc[2] }
    elseif bosrcsue == 3 { bosrcsue = 4 ; UserTellBosrc[3] }
    else { UserTellBosrc[RAND(4)] }
    --
    "\x"+NastoliaBosrc
}
NastoliaBosrc
{
"\*\![set,autoscroll,disable]\0\s[%(bsus+1)]\b[2]\_b[img/%(userimg).png,10,10,--option=use_self_alpha]\f[name,%(zitai)]"
--
"\![*]向波斯尔泰询问：\n/
\_l[35,-]\q[你怎样找到我的？,BosrcQ1]\n/
\_l[35,-]\q[你住在精卫里面吗？,BosrcQ2]\n/
\_l[35,-]\q[你去过纳米恩图吗？,BosrcQ3]\n/
\_l[35,-]\q[你会飞行吗？,BosrcQ4]\n/
\![*]\q[离开,pamamu]\e"
}
Choice.BosrcQ1
{ if !aoiBosrcQ1 { aoiBosrcQ1 = 1 ; pont++ } Sueia04 }
Choice.BosrcQ2
{ if !aoiBosrcQ2 { aoiBosrcQ2 = 1 ; pont++ } Sueia05 }
Choice.BosrcQ3
{ if !aoiBosrcQ3 { aoiBosrcQ3 = 1 ; pont++ } Sueia06 }
Choice.BosrcQ4
{ if !aoiBosrcQ4 { aoiBosrcQ3 = 1 ; pont++ } Sueia07 }
//*****关于大树********************
Choice.likanandasa
{
    _head = "%(year)%(wisjikan(month))%(wisjikan(day))"
    void SRAND(TOINT(_head+1217))
    _index = RAND(11)
    { <<"
        \c【旁白2】\s[2000]古老的大树开满了像由玻璃碎屑插成的花，她就像一面镜子，
        仔细观察，玻璃上立马变成了由透明的花瓣边缘渐变到无芯的花蕊的%(AjaluList[_index])。
        \c\1【user】我记得波斯尔泰说过，黄色代表迷茫，蓝色代表抑郁，绿色代表逃避……
        那我看到的是%(AjaluList[_index*2])，是%(AjaluList[_index*2+1])的意思？
    ">> }
    {
        "【旁白2】\s[2000]大树仍然是支离破碎的样子，\w8\w4完全看不清形状和颜色，\w8\w4突然间脑袋闪过一个画面：\w8\w8（"
        --
        Sasye01
        Sasye02
        Sasye03
        Sasye04
        --
        "）"
    }
    if RAND(100) > 97 { "\f[name,%(zitai)]"+GetTama }
    if RAND(100) < 28 { "\f[name,%(zitai)]"+GetMono }
}
AjaluList : array
{
"\f[color,102,204,255]浅蓝\f[color,default]";"感官过载"
"\f[color,139,187,233]普蓝\f[color,default]";"无能为力"
"\f[color,74,138,202]蓝色\f[color,default]";"抑郁"
"\f[color,251,148,166]桃红\f[color,default]";"自以为是"
"\f[color,247,119,127]浅红\f[color,default]";"自我对立"
"\f[color,208,32,53]红色\f[color,default]";"孤独"
"\f[color,153,204,153]浅绿\f[color,default]";"温柔善良"
"\f[color,99,157,147]普绿\f[color,default]";"无法承受"
"\f[color,37,83,75]深绿\f[color,default]";"逃避"
"\f[color,255,204,51]黄色\f[color,default]";"迷茫"
"\f[color,152,40,24]紫色\f[color,default]";"焦虑"
}
//***** 剧情进展函数END↑--------------------------------------------------------------------------------------------------------------------------------------------
//***** 光玉、药房、打工↓--------------------------------------------------------------------------------------------------------------------------------------------
//*****光玉、花瓣、辉屑********************
GetTama
{
    _nu = RAND(3)
    hasa++
    glasu[_nu]
    --
    "\![set,trayballoon,--icon=info,--timeout=10,--text=光玉+1]"
}
glasu : array
{
    "【玉响】散布在世界各地的玉响，有欢声笑语也有下着祝福的雨"
    "【花瓣】飘落到世界缝隙的花瓣，有延绵的悲伤也有纯粹的天空"
    "【辉屑】穿梭异界时粘附在身上的碎片，似乎能映射另一个世界"
}
//*****病房********************
Choice.atashi 
{
    AtashiSueia
    if RAND(100) > 98 ; GetTama
    if RAND(100) < 28 ; GetMono
}
//*****药房********************
OnwanNeRoom
{
    if !aoiWanNe ; NaoiWanNe
    --
    //获取Hetsislist
    if RE_GREP(boottia,'[夜晚]') ; "\0\s[1001]" ; else ; "\0\s[1000]"
    --
    "\b[2]\*\![set,autoscroll,disable]\_b[img/npc1.png,10,10,--option=use_self_alpha]\f[name,%(zitai)]【药房】\n/
    您好，有什么可以帮到您？\_q\n/
    \n/
    \n/
    %(ANY('【花瓣】','【玉响】','【辉屑】'))目前获得的光玉：%(EXIF(hasa,,TOSTR('0')))\n/
    \![*]\q[返回,pamamu]/
    \1\s[10]\b[4]\![set,autoscroll,disable]\_l[64,-]【药库】/
    %(Hetsislist(0))/
    "
}
Hetsislist
{
    
    if !SAORI(sqloridllpath,"OPEN",'sqlori.db') { "\f[name,%(zitai)]打开数据库出错" ; UNLOADLIB(sqloridllpath) ; return ; }
    _list = IARRAY
    _type = ''
    _txt = ''
    _list = SAORI(sqloridllpath, 'EXEC', "SELECT * FROM hetsis;")
    _list = SPLIT(_list,'0idtypenamenunutextgolddata')[1]
        void RE_SPLIT(_list,'([^]+){5}[^]+?')
        _list = RE_GETSTR()
        _list = ASORT(_list)
        for _i=0 ; _i<ARRAYSIZE(_list) ; _i++ {
            _lilist = SPLIT(_list[_i],'')
            if _type != _lilist[1] { _type = _lilist[1] ; _txt += "\n\f[bold,1]💊 "+_lilist[1]+"\f[bold,0]\n" }
            _txt += "%(tabimg[RAND(7)])\q["+_lilist[2]+",Onhetsistext,"+_lilist[4]+","+_lilist[2]+"]\n拥有："+_lilist[3]+"        \[\q["
            if !_argv[0] ; _txt += "购买,Onbuyhetsis,"+_lilist[2]+","+_lilist[5]+","+_lilist[3]
            else ; _txt += "服用,Oneathetsis,"+_lilist[2]+","+_lilist[3]+","+TOSTR(_lilist[6])
            _txt += "]]\n"
        }
    void SAORI(sqloridllpath,"CLOSE",'sqlori.db')
    UNLOADLIB(sqloridllpath)
    _txt
}
Onhetsistext
{ "\*\![set,autoscroll,disable]\0\s[%(bsus)]\b[0]\![*]\f[bold,1]"+reference1+"\f[bold,0]\n%(tabimg[RAND(7)])"+reference0+"\n\n\n\![*]\q[返回,OnwanNeRoom]" }
Onbuyhetsis
{
    "\*\![set,autoscroll,disable]\0\s[10]\b[2]\_b[img/npc1.png,10,10,--option=use_self_alpha]\f[name,%(zitai)]\_q【购买】\n/
    请问是否确认购买%(reference0)？\n/
    \n/
    \n/
    \_l[15,-]\q[是,Onchkbuy,%(reference0),%(reference1),%(reference2)]\_l[60,-]\q[否,OnwanNeRoom]\n/
    \![*]\q[返回,pamamu]"
}
Onchkbuy
{
    if TOINT(reference1) > TOINT(hasa) { "\*\0\s[10]\b[2]\_b[img/npc1.png,10,10,--option=use_self_alpha]\f[name,%(zitai)]光玉不够……\n\![*]\q[返回,OnwanNeRoom]" ; return }
    if !SAORI(sqloridllpath,"OPEN",'sqlori.db') { "\f[name,%(zitai)]打开数据库出错" ; UNLOADLIB(sqloridllpath) ; return ; }
    hasa -= TOINT(reference1)
    _flag = SAORI(sqloridllpath, 'EXEC', "UPDATE hetsis SET nunu = '%(TOINT(reference2)+1)' WHERE name = '%(reference0)';")
    void SAORI(sqloridllpath,"CLOSE",'sqlori.db')
    UNLOADLIB(sqloridllpath)
    "\*\0\s[10]\b[2]\_b[img/npc1.png,10,10,--option=use_self_alpha]\f[name,%(zitai)]已购买%(reference0)一粒。\n\![*]\q[返回,OnwanNeRoom]\e"
}
tabimg : array
{
"\_b[img/lit22.png,inline,--option=use_self_alpha]"
"\_b[img/tab06.png,inline,--option=use_self_alpha]"
"\_b[img/tab05.png,inline,--option=use_self_alpha]"
"\_b[img/tab02.png,inline,--option=use_self_alpha]"
"\_b[img/tab01.png,inline,--option=use_self_alpha]"
"\_b[img/tab03.png,inline,--option=use_self_alpha]"
"\_b[img/tab04.png,inline,--option=use_self_alpha]"
}
//*****打工********************
Onbaito
{
    if StartBaito != 0 ; Nowtime = GETSECCOUNT
    if !aoiBaito ; NaoiBaito
    --
    "\0\s[%(bsus)]\b[2]\_b[img/%(userimg).png,10,10,--option=use_self_alpha]\f[name,%(zitai)]\_q【打工】\n\n[half]/
    \_l[25,-]\![*]%(EXIF((Nowtime-StartBaito)>21600,'\q[领取上一份工资,BaitoGET1]','\q[和波斯尔泰一起打工,BaitoStart1]'))\n/
    \_l[25,-]\![*]\q[帮gent写作业,BaitoStart2]\n/
    \n[half]\n/
    \![*]\q[返回,pamamu]/
    "
}
Choice.BaitoStart1
{
    if Nowtime < EndBaito { "【bosrc】正在打工中呢，请加油！" ; return }
    StartBaito = GETSECCOUNT
    EndBaito = GETSECCOUNT+21600
    --
    Muuglas01
}
Choice.BaitoGET1
{ hasa+=6 ; StartBaito = 0 ; EndBaito = 0 ; Nowtime = 0 ; "\![set,trayballoon,--icon=info,--timeout=10,--title=打工报酬,--text=光玉+6]【bosrc】\s[%(bsus+4)]打工已经，结束了呢，一共收获6个光玉。" }



Choice.BaitoStart2
{
    guid = TOSTR(SAORI("saori/guid_saori.dll","")) ; void UNLOADLIB("saori/guid_saori.dll")
    _time = year+"年"+month+"月"+day+"日"
    _quslist = IARRAY
    _cisu = 0
    
    if !SAORI(sqloridllpath,"OPEN",'sqlori.db') { "\1\s[%(gsus)]\f[name,%(zitai)]打开数据库出错" ; UNLOADLIB(sqloridllpath) ; return ; }
    _list = SAORI(sqloridllpath, 'EXEC', "SELECT * FROM jvben WHERE guid == '%(guid)' AND npcname == 'gent' ;")
    _list = SPLIT(_list,'0guidnpcnamedatatime')
    if ARRAYSIZE(_list) < 2 {
        _flag = SAORI(sqloridllpath, 'EXEC', "INSERT INTO jvben VALUES('%(guid)', 'gent', '6', '%(_time)' );")
        _cisu = 6 }
    else { 
        _data = SPLIT(_list[1],'') ; _cisu = _data[2] ; _gettime = _data[3]
        if _gettime != _time {
            _flag = SAORI(sqloridllpath, 'EXEC', "UPDATE jvben SET time = '%(_time)' , data = '6' WHERE guid == '%(guid)' AND npcname == 'gent' ;")
            _cisu = 6 ; _time = _data[3]
        }
    }
    
    
    if _cisu <= 0 { "【gent】作业做完了，不能再给你光玉了。" ; return ; }

    void SAORI(sqloridllpath,"CLOSE",'sqlori.db')
    UNLOADLIB(sqloridllpath)

    Muuglas02
}
OnNastolia
{
    guid = TOSTR(SAORI("saori/guid_saori.dll","")) ; void UNLOADLIB("saori/guid_saori.dll")
    if !SAORI(sqloridllpath,"OPEN",'sqlori.db') { "\1\s[%(gsus)]\f[name,%(zitai)]打开数据库出错" ; UNLOADLIB(sqloridllpath) ; return ; }
    //检查答案，reference1答案，reference3问题
    if reference0 {
        _alisflag = 0
        if reference0 == 2 {
            _qus = SAORI(sqloridllpath, 'EXEC', "SELECT zito FROM nanmun WHERE chines == '%(reference3)';")
            _qus = SPLIT(_qus,'0zito')[1]
            _qus = SPLIT(_qus,'')
            for _i=0 ; _i<ARRAYSIZE(_qus) ; _i++ {
                if reference1 == _qus[_i] { _alisflag = 1 ; break }
            }
        }elseif reference0 == 3 {
            _qus = SAORI(sqloridllpath, 'EXEC', "SELECT chines FROM nanmun WHERE zito == '%(reference3)';")
            _qus = SPLIT(_qus,'0chines')[1]
            _qus = SPLIT(_qus,'')
            for _i=0 ; _i<ARRAYSIZE(_qus) ; _i++ {
                if reference1 _in_ _qus[_i] && reference1 != '' { _alisflag = 1 ; break }
            }
        }
        if _alisflag { hasa += 1 ; "\![set,trayballoon,--icon=info,--timeout=10,--title=恭喜答对了,--text=光玉+1]" }
        else ; "\![set,trayballoon,--icon=info,--timeout=10,--text=很遗憾没答对]"
    }
    --

    //检验次数
    _cisuku = SAORI(sqloridllpath, 'EXEC', "SELECT data FROM jvben WHERE guid == '%(guid)' AND npcname == 'gent' ;")
    _cisuku = SPLIT(_cisuku,'0data')[1]
    _cisuku = TOINT(_cisuku)-1
    if _cisuku >= 0 { _flag = SAORI(sqloridllpath, 'EXEC', "UPDATE jvben SET data = '%(_cisuku)' WHERE guid == '%(guid)' AND npcname == 'gent' ;") }
    else { "【gent】作业做完了，不能再给你光玉了。"    ; return ; }

    //获取数据
    _quslist = SAORI(sqloridllpath, 'EXEC', "SELECT * FROM nanmun ORDER BY RANDOM() LIMIT 3;")
    _quslist = SPLIT(_quslist,'0idzitochines')
    if ARRAYSIZE(_quslist) < 2 { "\1\s[%(gsus)]\f[name,%(zitai)]数据库出错" ; UNLOADLIB(sqloridllpath) ; return ; }
    _quslist = _quslist[1]
    void RE_GREP(_quslist,'\d+[\w->]+[\D]+')
    _list = RE_GETSTR()

    //题目数据
    _qoslist1 = IARRAY
    _Nastolia = IARRAY
    for _i=0 ; _i<3 ; _i++ {
        _qi = SPLIT(_list[_i],'')
        _qoslist1 ,= _qi[1]
        _Nastolia ,= _qi[2]
    }
    _ti = ''
    _da = IARRAY
    _ty = 1
    if RAND(2) { _ti = _qoslist1[RAND(3)] ; _da = _Nastolia ; _ty = 3 } else { _ti = _Nastolia[RAND(3)] ; _da = _qoslist1 ; _ty = 2 }

    //题目
    "\t\*\![set,autoscroll,disable]\1\s[%(gsus)]\f[name,%(zitai)]/
    - > %(6-TOINT(_cisuku)). 「%(_ti)」的翻译是什么：\n\n[half]/
    \_l[45,-]%(ANY('【花瓣】','【玉响】','【辉屑】'))\q[%(_da[0]),OnNastolia,%(_ty),%(_da[0]),0,%(_ti)]\n/
    \_l[45,-]%(ANY('【花瓣】','【玉响】','【辉屑】'))\q[%(_da[1]),OnNastolia,%(_ty),%(_da[1]),0,%(_ti)]\n/
    \_l[45,-]%(ANY('【花瓣】','【玉响】','【辉屑】'))\q[%(_da[2]),OnNastolia,%(_ty),%(_da[2]),0,%(_ti)]\n/
    \n[half]\![*]\q[返回,Onbaito]"

    void SAORI(sqloridllpath,"CLOSE",'sqlori.db')
    UNLOADLIB(sqloridllpath)
}
Muuglas01
{ <<"
\c\0\s[%(bsus)]【user】打工开始，
【bosrc】\s[%(bsus+4)]加油哦，我就在护士站工作，
有不懂的问题可以问我。
\![*]\q[返回,pamamu]
">> }
Muuglas02
{ 
<<"
【gent】好了，嗯……帮我写这份喃语科吧。
只有选择题，只要选择喃语对应的中文释义，或者中文意思对应的喃语词汇就行了。
\n\n[half]%(lisL('开始答题'))\n\n\n[half]\![*]\q[返回,pamamu]\x\![raise,OnNastolia,0,0,0,0]
">> }



//*****新闻********************
Choice.news
{
    "\*\![set,autoscroll,disable]"
    --
    if RE_GREP(boottia,'[夜晚]') ; "\0\s[1001]" ; else ; "\0\s[1000]"
    --
    "\b[2]\_b[img/mnaia.png,10,10,--option=use_self_alpha]\f[name,%(zitai)]/
    \![*]\![*]\q[【新闻】,news,放在医院宣传栏的报纸，上面的信息应该很旧了]\f[sub,1]\q[[看不懂？\],OnOpenlink,https://sikan.moe/elks/]\f[sub,0]\n\n[half]/
    \_l[15,-]\![*]%(newsName)\n/
    \_l[15,-]\![*]%(newsName)\n/
    \_l[15,-]\![*]%(newsName)\n/
    \n[half]\![*]\q[返回,pamamu]"
}
newsName
{
"\q[《滔天巨浪来临，世界进入静寂季》,OnShowNeiso,1]"
"\q[《被海水包围，却不是在海底的生活》,OnShowNeiso,1]"
"\q[《震惊！三万岁的大前辈现身！》,OnShowNeiso,1]"
"\q[《静寂季退去，琼斯王子登基！》,OnShowNeiso,1]"
"\q[《地旋中学集体自杀事件》,OnShowNeiso,1]"
"\q[《第一次记忆战争》,OnShowNeiso,1]"
"\q[《新的疾病，新的挑战，记忆战争后遗症》,OnShowNeiso,1]"
"\q[《琼斯国王撤国！厄尔科斯走向境界彼岸》,OnShowNeiso,1]"
"\q[《试飞摔伤的她，第二天还在上学》,OnShowNeiso,1]"
"\q[《又遇海难，居民都很淡定，无人逃跑》,OnShowNeiso,1]"
"\q[《一张本大陆东南片区地图》,elkschito,也就是主角们发生故事的主要地点]"
"\q[《愚女坡地铁线路图》,matokakukoumi,也就是gent口中所说的“∩”形地铁]"
}
OnShowNeiso
{ 
    "\*\![set,autoscroll,disable]"
    --
    if RE_GREP(boottia,'[夜晚]') ; "\0\s[1001]" ; else ; "\0\s[1000]"
    --
    "\b[2]\_b[img/mnaia2.png,10,10,--option=use_self_alpha]\f[name,%(zitai)]"
    --
    newsNeiso[reference0]
}
Choice.elkschito
{ OnOpenfile(pakeilo+'img/map.jpg') }
Choice.matokakukoumi
{ "\*\![set,autoscroll,disable]%(EXIF(RE_GREP(boottia,'[夜晚]'),'\0\s[1001]','\0\s[1000]'))\b[0]\_b[img/kukoumi.png,10,10,--option=use_self_alpha]\f[name,%(zitai)]\n\n\n\n\n\![*]\q[返回,news]" }



//***** 光玉、药房、打工、新闻END↑--------------------------------------------------------------------------------------------------------------------------------------------
//***** 我的信息、信物、好感、san、吃药↓--------------------------------------------------------------------------------------------------------------------------------------------
//*****我的信息********************
Choice.uewedio
{
    _level = (100-Puoleij)/10.0*1+((100-Pusozn)/100.0)
    "\*\![set,autoscroll,disable]\_q\0/
    \b[2]\_b[img/%(userimg).png,10,10,--option=use_self_alpha]\f[name,%(zitai)]【%(username)】"
    --
    
    _time =  "%(year)%(wisjikan(month))%(wisjikan(day))"
    void SRAND(TOINT(_time)+614)
    if _level >= 5 { "\q[%(Leipu[RAND(15)])  中,Tell]，" }
    void SRAND()
    --
    "痛苦等级：\f[color,208,32,53]%(TOINT(_level))\f[color,default]\n/
    \q[全名,uewedio,在设置里是名称，第一栏的那个]：%(userFullname)\f[sub,1]\q[修改,mesesg]\f[sub,0]          san：\f[color,207,34,54]%(TOINT(san))\f[color,default]\n/
    性别：%(usersex)           年龄：16\n/
    生日：%(userbirthday[1])月%(userbirthday[2])日\n/
    种族：太阳族\n/
    状态：%(minnu[1])    %(ChkNu(minnu[0]))            \q[[详细状况\],static]\n/
    \![*]\q[返回,pamamu]         \![*]\q[下一页,bosuewe]/
    "
}
minnu
{
    if Pulosu <= Puwasn && Pulosu <= Pulosa { (Pulosu,'抑郁') }
    elseif Puwasn<= Pulosa { (Puwasn,'焦虑') }
    else ; { (Pulosa,'躁狂') }
}
ChkNu
{
    if _argv[0] >= 0 && _argv[0] < 40 { "\f[color,37,83,75]重度\f[color,default]" }
    elseif _argv[0] >= 40 && _argv[0] < 60 { "\f[color,251,148,166]中度\f[color,default]" }
    elseif _argv[0] >= 60 && _argv[0] <= 100 { "\f[color,74,138,202]轻度\f[color,default]" }
}
Leipu : array
{ "呼吸障碍";"锥体外系反应";"睡眠障碍";"视野模糊";"嗜睡";"脚伤痕痛";"手腕伤痕痛";"胸内内脏痛";"肋骨痛";"耳闷";"头痛";"头晕";"心悸";"惊恐";"解离" }
Choice.bosuewe
{
    "\*\![set,autoscroll,disable]\_q\0/
    \b[2]\_b[img/bosrc.png,10,10,--option=use_self_alpha]\f[name,%(zitai)]【波斯尔泰】    好感度：\f[color,251,148,166]%(Kokoro(intimacy))\f[color,default]\n/
    全名：愚女坡·波斯尔泰          maiu-sotuo-oka bosrotai\n/
    性别：森都一族         年龄：14\n/
    生日：1月1日\n/
    种族：森都一族\n/
    \![*]\q[返回,pamamu]         \![*]\q[下一页,genuewe]/
    "
}
Choice.genuewe
{
    "\*\![set,autoscroll,disable]\_q\0/
    \b[2]\_b[img/gent.png,10,10,--option=use_self_alpha]\f[name,%(zitai)]【 gent 】    好感度：\f[color,251,148,166]%(Kokoro(intimacy2))\f[color,default]\n/
    全名：黄·菱叶      neline gent\n/
    性别：♀女           年龄：15\n/
    生日：9月3日\n/
    种族：太阳族\n/
    \![*]\q[返回,pamamu]         \![*]\q[下一页,uewedio]\1\s[%(gsus)]/
    "
}
//好感度    ❤ ♥ 💕 💜 ♡ 💗
Kokoro
{ case _argv[0] {
    when 0-9 ; "❤❤❤❤❤"
    when 10-19 ; "♥❤❤❤❤"
    when 20-29 ; "♥♥❤❤❤"
    when 30-39 ; "♥♥♥❤❤"
    when 40-49 ; "♥♥♥♥❤"
    when 50-59 ; "♥♥♥♥♥"
    when 60-69 ; "💕♥♥♥♥"
    when 70-79 ; "💕💕♥♥♥"
    when 80-89 ; "💕💕💕♥♥"
    when 90-99 ; "💕💕💕💕♥"
    others ; "💕💕💕💕💕"
}}



//*****san值与吃药********************
//更新数据
TeliDatabase
{
    guid = TOSTR(SAORI("saori/guid_saori.dll","")) ; void UNLOADLIB("saori/guid_saori.dll")
    if !SAORI(sqloridllpath,"OPEN",'sqlori.db') { "\f[name,%(zitai)]打开数据库出错" ; UNLOADLIB(sqloridllpath) ; return ; }
    
    _data = (san,Pulosu,Puwasn,Pulosa,Puoleij,Pusozn)
    _time = year+"年"+month+"月"+day+"日"
    _flag = 0
    
    _list = SAORI(sqloridllpath, 'EXEC', "SELECT * FROM jvben WHERE guid == '%(guid)' AND npcname == 'system' ;")
    _list = SPLIT(_list,'0guidnpcnamedatatime')
    if ARRAYSIZE(_list) < 2 {
        _flag = SAORI(sqloridllpath, 'EXEC', "INSERT INTO jvben VALUES('%(guid)', 'system', '%(TOSTR(_data))', '%(_time)' );")
        oudata = (Pulosu,Puwasn,Pulosa,Puoleij,Pusozn)
    } else { 
        _getlist = SPLIT(_list[1],'') ; _getdata = _getlist[2] ; _gettime = _getlist[3]
        
        if _gettime != _time {
            void Tolog('')
            void Tolog('【'+_time+'】')
            void Tolog('    san减去前：'+TOREAL(san))
                Chksan    //san值减去
            void Tolog('    san减去后：'+TOREAL(san))
            void Tolog('----------------------------------')
                _data = (san,Pulosu,Puwasn,Pulosa,Puoleij,Pusozn)
                _setin1 = TOSTR(_data)
                _setinlis1 = REPLACE(_setin1,',',' | ')
            void Tolog('    状态重置前：'+_setinlis1)
                ResetTeli    //重置状态值
                _data = (san,Pulosu,Puwasn,Pulosa,Puoleij,Pusozn)
                oudata = (Pulosu,Puwasn,Pulosa,Puoleij,Pusozn)
                _setin2 = TOSTR(_data)
                _setinlis2 = REPLACE(_setin2,',',' | ')
            void Tolog('    状态重置后：'+_setinlis2)
            void Tolog('')
                f9pluslis = (0,0,0,0,0)    //重置表
                _flag = SAORI(sqloridllpath, 'EXEC', "UPDATE jvben SET time = '%(_time)' , data = '%(TOSTR(_data))' WHERE guid == '%(guid)' AND npcname == 'system' ;")
        }
    }

    void SAORI(sqloridllpath,"CLOSE",'sqlori.db')
    UNLOADLIB(sqloridllpath)
}
//吃药
//reference0名字，reference1库存，reference2需要更新的数据
//TeliDatabase == 1 时，更新了数据
Oneathetsis
{
    _flag1 = TeliDatabase
    if !reference1 { "\f[name,%(zitai)]库存不够" ; return ; }
    guid = TOSTR(SAORI("saori/guid_saori.dll","")) ; void UNLOADLIB("saori/guid_saori.dll")
    if !SAORI(sqloridllpath,"OPEN",'sqlori.db') { "\f[name,%(zitai)]打开数据库出错" ; UNLOADLIB(sqloridllpath) ; return ; }

    oudata = (Pulosu,Puwasn,Pulosa,Puoleij,Pusozn)
    _updata = SPLIT(reference2,';')
    _teli = ('','Pulosu','Puwasn','Pulosa','Puoleij','Pusozn')
    for _i = 0 ; _i < 2 ; _i++ { 
        void EVAL(_updata[_i])
        _f9 = SPLIT(_updata[_i],'+=')
        if (_b = ASEARCHEX(_f9[0],_teli)) ; f9pluslis[_b-1]+=TOINT(_f9[1])
    }
    _nowdata = (san,Pulosu,Puwasn,Pulosa,Puoleij,Pusozn)
    _time = year+"年"+month+"月"+day+"日"
    _flag2 = SAORI(sqloridllpath, 'EXEC', "UPDATE jvben SET time = '%(_time)' , data = '%(TOSTR(_nowdata))' WHERE guid == '%(guid)' AND npcname == 'system' ;")

    reference1 -= 1
    _flag3 = SAORI(sqloridllpath, 'EXEC', "UPDATE hetsis SET nunu = '%(reference1)' WHERE name == '%(reference0)' ;")

    void SAORI(sqloridllpath,"CLOSE",'sqlori.db')
    UNLOADLIB(sqloridllpath)
}
//重置状态值
ResetTeli
{
    _r = 0 ; _dou = 0
    if pont < 7 { _r = 101 ; _dou = 0 }
    elseif pont >= 7 && pont < 100 { _r = 81 ; _dou = 20 }
    elseif pont >= 100 && pont < 500 { _r = 71 ; _dou = 30 }
    else { _r = 61 ; _dou = 40 }
    
    Pulosu = RAND(_r)+_dou    //抑郁
    Puwasn = RAND(_r)+_dou    //焦虑
    Pulosa = RAND(_r)+_dou    //躁狂
    Puoleij = RAND(_r)+_dou    //疼痛
    Pusozn = RAND(_r)+_dou    //耐受
}
//san值减去
Chksan
{
if (_a = Pulosu-50) < 0 ; san+=TOREAL(_a/10.0)
if (_a = Puwasn-50) < 0 ; san+=TOREAL(_a/10.0)
if (_a = Pulosa-50) < 0 ; san+=TOREAL(_a/10.0)
if (_a = Puoleij-50) < 0 ; san+=TOREAL(_a/10.0)
if (_a = Pusozn-50) < 0 ; san+=TOREAL(_a/10.0)
}



//*****物品箱********************
Choice.mono
{
    "\0\s[1000]\b[2]\*\![set,autoscroll,disable]\_b[img/mnsotuo2.png,10,10,--option=use_self_alpha]\f[name,%(zitai)]【物品箱】\n/
    这些……是您收集的吗？\_q\n/
    \![*]\![*]\![*]\![*]\![*]\![*]\![*]\![*]\![*]\![*]\![*]\![*]\![*]\![*]\f[size,14]\n[half]"
    --
    _txx = ""
    for _i=0 ; _i<20 ; _i++ {
        if monolist[_i] { _txx += "\_l[15,-]\q[%(monoIcon)%(monoName[_i]),Onmono,%(monoText[_i]),%(_i)]「%(monolist[_i])」\n" }
    }
    _txx
    --
    "\n[half]/
    \![*]\q[返回,pamamu]/
    \1\s[10]\b[4]\![set,autoscroll,disable]\_l[64,-]【药库】%(Hetsislist(1))/
    "
}
monoIcon
{'🌸';'🌺';'🌻';'🌹';'🌷';'🌼';'🍂';'🍀'}
monoName : array
{ "陌生人的照片";"岳环⇔愚女坡车票";"很厚的手记手账";"青色的头绳发带";"很皱的试卷";"留置针针头";
"不知用处的咒文符";"未开封的备皮刀";"蝴蝶胸针";"紫色的运动手腕";"奶白色的茶杯";"暗黄色的魔法结晶";
"很长的奶茶小票";"很大一只小熊玩偶";"花亭世界（异界）地图";"CD《琳琅》";"SOLO专业监听耳机";
"《森罗万象境界录》";"精卫出院纪念袋";"CD《勇气之翼》" }
Onmono
{
    "\*\![set,autoscroll,disable]"
    --
    if TOINT(reference1) == 18 {
        OnOpenfile(pakeilo+'img/IMG_3587.jpg')
    }
    --
    "\0\s[1000]\b[2]\_b[img/mnsotuo.png,10,10,--option=use_self_alpha]\f[name,%(zitai)]【%(monoName[reference1])】\n/
    \_l[30,-]%(reference0)\n/
    \![*]\q[送给波斯尔泰,OnJilp,0,%(reference1)]       \![*]\q[送给gent,OnJilp,1,%(reference1)]\n/
    \![*]\q[返回,mono]/
    "
}
OnJilp
{
    if !reference0 {
        if TOINT(monolist[reference0]) <= 0 { "【bosrc】\s[%(bsus+7)]欸？%(monoName[reference0])丢了吗？\w8\w8\w8" ; return }
        "【bosrc】%(JilpBosrc[reference0])"
        intimacy++
        monolist[reference0]--
        if intimacy > 100 ; intimacy = 100
    } else {
        if TOINT(monolist[reference0]) <= 0 { "【gent】\s[%(gsus+1)]%(monoName[reference0])是吗？\w8\w8\w8放心，\w8\w4迟早还会有的" ; return }
        "【gent】%(JilpGent[reference0])"
        intimacy2++
        monolist[reference0]--
        if intimacy2 > 100 ; intimacy2 = 100
    }
}


//=================================================================
//**** 信物 ------------------------------------------------------------------
monoText : array
{
"放在公共自行车的车筐上的一张照片，似乎被照片主人遗忘了很久，照片乃过去之物……"
"和波斯尔泰和gent三人一起去了异界展，那时候很开心，但又觉得有点担心和失落"
"出院了的一位病友给我的一本手账，里面贴满很漂亮的剪贴画，这份心意会待在我心里很久吧"
"波斯尔泰顺手给我的发带，绑在头发上感觉有种少数民族的感觉（就是波斯尔泰的森都一族）"
"发现时躺在草地上，似乎试卷主人抓着她哭了很久，而且还刚丢失不久，试卷主人抛弃她了吗"
"这是护士给我输液的时候……什么？我拔出来的？我又发作了？"
"上面写着res-iem to re-nya et E-neshtear , Liz-na，也是波斯尔泰给我的，不知道有什么用"
"听说刀片很锋利，或许可以拿来做某些事情，啊，护士来了（转身顺走）"
"逛街时一位在举办活动的姐姐送我的，她说和我很配？但我看起来这么闪耀的胸针跟我实在不配"
"gent给的手腕，她以前买的没用过，不过现在也不需要了，她看了看我的手腕，说可能会用到"
"之前波斯尔泰不小心打碎了我原先的茶杯，就买了个奶白色的茶杯给我，我挺喜欢的"
"在逛天狼阵时一位姐姐送的，我和波斯尔泰和gent研究了好久都不知道怎样使用"
"什么？现在的奶茶小票都开始写小说了？为了看完小说内容，我们买了很多奶茶"
"gent送我的，她觉得我很缺安全感，希望这个玩偶能给我些安定"
"啊！！！好喜欢花亭世界！看着地图就像来到了花亭世界一样，自由魔法会也在那里呢"
"上古时期的产物了，按照正确的历史起码有十年以上的CD，不过按照现在的时间才发行了四年"
"波斯尔泰知道我有点阿斯伯格特质，就送了这个耳机我，这个耳机能清楚地解析44.1khz的音频"
"这个是讲述厄尔科斯在始祖时期的世界，那时候整个世界都是消逝一族和森都一族的（我认同）"
"这个袋子很流行吗？愚女坡精卫出院不送袋子啊，好吧，原来是定制的，后来定制了一个青色的"
"不知为什么，这片CD里面的歌曲很让人共鸣，或许我们的处境和歌曲里面的歌词描述一致吧"
}
JilpBosrc : array
{
"这照片上的人是谁？嗯……确实有点古老感，虽然我很讨厌有自己的照片，不过从这张照片能看到安心感。"
"是啊，异界展真的很热闹，一整天都在走路，回来后腿都要废了，下一届异界展我们还要去参加~"
"病友给的手账啊，（或许我也做个手账？），嗯……都是些从别的地方剪下来的图画贴起来，看来很耗素材。"
"欸？我什么时候给过你青色发带了？不过既然是我给你的，那你就收下吧，我觉得绑在你头发上也很好看~"
"诶呀，真是张糟糕的试卷，不过和我不同，我以前是被霸凌才胡乱撕自己的试卷，然后就丢在学校边的草地上。"
"诶呀，这是从哪里顺过来的吗？掉出来了吗？针管会不会滞留在里面……好吧，你说没事就行，我会帮你保密的。"
"呃……我也忘了，到底什么时候给你的？不过我记得这是一串关于恋爱的符文，唔……好像我在异界展上买的？"
"呃……%(username)总会给我一些奇怪的东西，不过我会帮你保密的，我希望你会把这把刀用在正经用途上的吧……"
"这个胸针好漂亮，隐隐约约能感受到她原本的贵重，以及被普遍化之后的祥和，或许我能将这个胸针的故事感悟出来。"
"嗯……%(username)确实需要运动手腕，我的疤痕还不明显啦，我也不太想以后会用到，不过挺漂亮的，我就收下了。"
"之前的事情对不起啦，我也不知道你的茶杯会放在电脑主机上，我觉得%(username)要不要稍微收拾一下房间？"
"嗯……我也不懂魔法，不过这结晶挺好看的，你看这暗黄色的镶边像不像gent的眼睛？哈哈，别告诉gent，说我讲她。"
"这网文小说总算看完了，大概内容是主角打败了魔王之后失去了目标，于是弑神去了，简直是龙傲天的翻版。"
"哇！好漂亮！玩偶也好软，抱起来很舒服。这真的要送给我吗？好像很贵耶……那我就收下了，改天再回礼给你。"
"异界地图……第一次看到……但是这个花亭世界地图是层叠式绘制的，和一般鸟瞰式绘制不同，很有特色。"
"嗯……这片CD很好听，我就知道你会喜欢这些古老的东西，我这里要有一片《flip》，要不要借给你听？"
"怎么样……这款耳机好用吧，她和其他监听耳机不同，她是专门为了突显音频频率特征而制造的。"
"是啊，我很向往始祖时期的年代，那时候世界还是一片草原吧，万物始祖缔造了不同民族，万象始祖缔造了各种天象。"
"啊……这个袋子确实是定制的啦，除了愚女坡精卫版本还有其他的，比如山低精卫、云都精卫等……还真有种潮流的感觉。"
"听了确实会让人悲伤，这首歌的创作者原本也想作出充满勇气的音乐吧，可惜经过编曲后期的成品就是让人觉得惋惜。"
}
JilpGent : array
{
"诶呀，这照片上的人是谁？嗯……我也有时候会将有关自己的照片扔掉，因此被别人捡到也是挺常有的事。"
"那天可真是累啊，连来回坐车都是累的，下一届的话我想想吧，能不能多掏点钱用空间传送去啥的。"
"手账啊……我在以前的学校没见过有人做，不过我小学的时候确实有这种想法，后来不想剪下来变成了自己画。"
"这个发带式波斯尔泰的吧，怎样？我也绑上？确实有一番异族的感觉，不过还是波斯尔泰戴合适。"
"嗯……我也会这样做，不过现在复学，只要合格拿到毕业证就行了，成绩啥的再也不去看了。"
"欸……你把针头拔下来了？掉出来的？很危险欸。不过我会替你保密的，有时候我也想拔针头，整个手背都快要戳穿了。"
"看不懂这上面的文字，就这样放在手机壳里面会有什么效果吗？嗯……确实看到有人这样做？大概？那我也放进去好了。"
"备皮刀其实也就只是一般的刀片啦，锋利度不如美工刀、修眉刀，因为刀片本身很软，划起来不够顺手，因此疤痕会很浅。"
"好漂亮的胸针，谢谢，能帮我别上吗？嗯……我好像配不上这个胸针，里面承载的感情太重了，或许以前的我会喜欢。"
"怎样，运动手腕好用吗？不过我也觉得很反人类，接触疤痕的居然是粗糙的一面，光滑的一面确实露在外面的。"
"是吗……波斯尔泰不小心打碎了你的茶杯吗？你的房间真的需要收拾一下了，不过我也没有权说你，我也一样。"
"嗯……最近我一直在想怎样使用这个魔法结晶，听说她能够承载记忆，然后变成记忆结晶成为发动超能力的介质。"
"哇……这小票的小说终于看完了，也就是写勇者小队一路过关斩将弑神然后成为神的故事，很老俗的套路……"
"抱着玩偶舒服吗？是的，我也有一个同款的玩偶放在床上，被玩偶包围的感觉非常充满安心感，谢谢你。"
"异界地图啊……在异界展的时候我见你看了很久呢，我还想说要不要帮你买下来，那……放一份在我这里收藏好了。"
"嗯，很有特色的音乐。“民族风”？这种风格原来叫民族风啊，那我拿回去听一下了，%(username)的品味应该不差吧。"
"哇，是监听耳机！但事实监听是为了听清楚各轨音频之间的混合响度，而不是为了扒带准备的，%(username)喜欢扒带的吧。"
"始祖大人的那段历史确实充满着许多不确定性，但是alia的始祖大人至今还活着，我保持怀疑的态度，当然可能这段历史是被人为修改了。"
"这个纪念袋很有趣！我要定制一个南郊野版本的！配色就用深蓝色好了，跟泉都精卫挺搭的，不过这个愚女坡精卫的版本也很不错。"
"很可惜的一首歌，%(username)想要改编？加油！我很期待你的作品，把勇气之翼改编成充满勇气的音乐吧！"
}


Choice.mesesg
{ "\![open,configurationdialog,setup]" }
Choice.static
{ "\![open,aigraph]" }
//*****我的信息、信物、好感、san、吃药END↑--------------------------------------------------------------------------------------------------------------------------------------------
//***** 地図散步↓--------------------------------------------------------------------------------------------------------------------------------------------
OnStartChizuSanpo
{
    if !aoiChizusanpo ; NaoiChizusanpo
    --
    OnOpenfile(pakeilo+'template/Start.bat')
}
OnChizuSanpoe
//    \t  在jsstp.SEND()中毫无用处
{
    "\t\*\![set,windowstate,stayontop]"
    --
    case TOINT(reference1) {
        when 1 ; { if RAND() >27 ; ChizuWecweiala ; else ; GetMono }
        when 2 ; { if RAND() >27 ; ChizuFuweawalali ; else ; GetMono }
        when 3 ; { if RAND() >27 ; Chizufuweaweiala ; else ; GetMono }
        when 4 ; { if RAND() >27 ; Chizubukula ; else ; GetMono }
        when 5 ; { if RAND() >27 ; Chizudatasenta ; else ; GetMono }
        when 6 ; { if RAND() >27 ; ChizuHusiusansa ; else ; GetMono }
        when 7 ; { if RAND() >27 ; ChizuSibrposenta ; else ; GetMono }
        when 8 ; { if RAND() >27 ; ChizuKamokumuzumo ; else ; GetMono }
        when 9 ; { if RAND() >27 ; ChizuNamiLentu ; else ; GetMono }
        when 10 ; { if RAND() >27 ; ChizuMatokawalali ; else ; GetMono }
    }
    --
    "\![set,windowstate,!stayontop]\e%(tor=0)"
}
GetMono
{
    _a = RAND(20)
    monolist[_a]++
    GetMonoText(_a)
}



//***** 地図散步↑--------------------------------------------------------------------------------------------------------------------------------------------
//***** 存档↓--------------------------------------------------------------------------------------------------------------------------------------------
OnSaveLoad
{
    "\*\![set,autoscroll,disable]\_q"
    --
    if RE_GREP(boottia,'[夜晚]') ; "\0\s[1001]" ; else ; "\0\s[1000]"
    --
    "\b[2]\_b[img/mntag.png,10,10,--option=use_self_alpha]/
    \![*]存档：\n\n[half]/
    \_l[10,-]存档1\![*]%(ChkSaveLoad(1))   \[\q[save,OnSavee,1]]  \[\q[load,OnLoade,1]]\n/
    \_l[10,-]存档2\![*]%(ChkSaveLoad(2))   \[\q[save,OnSavee,2]]  \[\q[load,OnLoade,2]]\n/
    \_l[10,-]存档3\![*]%(ChkSaveLoad(3))   \[\q[save,OnSavee,3]]  \[\q[load,OnLoade,3]]\n/
    \n[half]\![*]\q[返回,pamamu]/
    "
}
ChkSaveLoad
{
    _qos = _argv[0]
    guid = TOSTR(SAORI("saori/guid_saori.dll","")) ; void UNLOADLIB("saori/guid_saori.dll")
    if !SAORI(sqloridllpath,"OPEN",'sqlori.db') { "\f[name,%(zitai)]打开数据库出错" ; UNLOADLIB(sqloridllpath) ; return ; }
    _list = SAORI(sqloridllpath, 'EXEC', "SELECT id,data,time FROM saveload WHERE guid == '%(guid)' AND id == '%(_qos)' ")
    _list = SPLIT(_list,'0iddatatime')
    if ARRAYSIZE(_list) < 2 {
        "（当前存档为空）"
    } else { 
        _t = GETTIME(SPLIT(_list[1],'')[2])
        _t[0]+"年"+_t[1]+"月"+_t[2]+"日"
    }
    void SAORI(sqloridllpath,"CLOSE",'sqlori.db')
    UNLOADLIB(sqloridllpath)
}
OnSavee
{
    _qos = reference0
    _nowdata = "san=%(TOSTR(san)) | "+/
                "hasa=%(TOSTR(hasa)) | "+/
                "Pulosu=%(TOSTR(Pulosu)) | "+/
                "Puwasn=%(TOSTR(Puwasn)) | "+/
                "Pulosa=%(TOSTR(Pulosa)) | "+/
                "Puoleij=%(TOSTR(Puoleij)) | "+/
                "Pusozn=%(TOSTR(Pusozn)) | "+/
                "f9pluslis=%(TOSTR(f9pluslis)) | "+/
                "oudata=%(TOSTR(oudata)) | "+/
                "gentsue=%(TOSTR(gentsue)) | "+/
                "bosrcsue=%(TOSTR(bosrcsue)) | "+/
                "pont=%(TOSTR(pont)) | "+/
                "monolist=%(TOSTR(monolist)) | "+/
                "intimacy=%(TOSTR(intimacy)) | "+/
                "intimacy2=%(TOSTR(intimacy2))"
    _time = GETSECCOUNT()
    guid = TOSTR(SAORI("saori/guid_saori.dll","")) ; void UNLOADLIB("saori/guid_saori.dll")
    if !SAORI(sqloridllpath,"OPEN",'sqlori.db') { "\f[name,%(zitai)]打开数据库出错" ; UNLOADLIB(sqloridllpath) ; return ; }
    _list = SAORI(sqloridllpath, 'EXEC', "SELECT id,data,time FROM saveload WHERE guid == '%(guid)' AND id == '%(_qos)' ")
    _list = SPLIT(_list,'0iddatatime')
    if ARRAYSIZE(_list) < 2 {
        _flag = SAORI(sqloridllpath, 'EXEC', "INSERT INTO saveload VALUES('%(guid)', '%(_qos)', '%(TOSTR(_nowdata))', '%(_time)' );")
    } else { 
        _flag2 = SAORI(sqloridllpath, 'EXEC', "UPDATE saveload SET time = '%(_time)' , data = '%(TOSTR(_nowdata))' WHERE guid == '%(guid)' AND id == '%(_argv[0])' ;")
    }
    void SAORI(sqloridllpath,"CLOSE",'sqlori.db')
    UNLOADLIB(sqloridllpath)
    OnSaveLoad
}
OnLoade
{
    _qos = reference0
    guid = TOSTR(SAORI("saori/guid_saori.dll","")) ; void UNLOADLIB("saori/guid_saori.dll")
    if !SAORI(sqloridllpath,"OPEN",'sqlori.db') { "\f[name,%(zitai)]打开数据库出错" ; UNLOADLIB(sqloridllpath) ; return ; }
    _list = SAORI(sqloridllpath, 'EXEC', "SELECT id,data,time FROM saveload WHERE guid == '%(guid)' AND id == '%(_qos)' ")
    _list = SPLIT(_list,'0iddatatime')
    if ARRAYSIZE(_list) < 2 {
        "（当前存档为空）"
    } else { 
        _getlist = SPLIT(_list[1],'')
        _data = SPLIT(TOSTR(_getlist),' | ')
        _TXT=TOSTR(_data[0][0])
        for _i=0 ; _i<ARRAYSIZE(_data) ; _i++ {
            if _i == 0 {
                _c = SPLIT(_data[_i][1],'=')
                LETTONAME("%(EVAL('_c[0]'))","%(TOREAL(_c[1]))") ;
            }
            elseif _i == 7 || ( _i == 8 || _i == 12 ) {
                _c = SPLIT(_data[_i],'=')
                LETTONAME("%(EVAL('_c[0]'))","%(_c[1])") ;
            }
            else {
                _c = SPLIT(_data[_i],'=')
                LETTONAME("%(EVAL('_c[0]'))","%(TOINT(_c[1]))") ;
            }
        }
    }

    void SAORI(sqloridllpath,"CLOSE",'sqlori.db')
    UNLOADLIB(sqloridllpath)
    OnSaveLoad
}



//***** 存档↑--------------------------------------------------------------------------------------------------------------------------------------------
//***** keyword↓--------------------------------------------------------------------------------------------------------------------------------------------
Onkeyword : array
{
    "\_q\f[name,%(zitai)]"
    --
    "【alia】\n\_l[35,-]厄尔科斯很古老一个种族，大部分天生拥有超能力的易感性，大部分alia都非常敏感，一但情绪或者环境不稳定时，她们会献祭牺牲。"
    "【那场飓风】\n\_l[35,-]近代花咲季在南郊野发生的一场万丈飓风事件，很多想死的人和献祭的alia还有不小心被卷入暴风眼的无辜居民都在此事件中丧生，此事件估计死亡失踪超过4万人。"
    "【███的她们】\n\_l[35,-]指和username一起约死的约死群里面的人。"
    "【波斯尔泰她们】\n\_l[35,-]指假装自己没病努力生活，硬扛过去的人们，不过大多数会加深病情。"
    "【森都一族】\n\_l[35,-]森都一族通常被误认为消逝一族，其实森都一族也有超能力的易感性，仅次于消逝一族，大多数森都一族都十分亲和森林，可以独自在森林中待很长时间。"
    "【她们】\n\_l[35,-]指和username一起约死的约死群里面的人。"
    "【消逝一族】\n\_l[35,-]在厄尔科斯称为alia，很古老的一个种族，她们的文明大概能追溯到3万年前，她们会为了这个世界而主动献祭牺牲。"
    "【alia们】\n\_l[35,-]约死群的她们认为alia们也是一起去赴死的。"
    "【刚看了第一次记忆战争的报道】\n\_l[35,-]username所在的年份是2041年，在2039年末旬政府的心灵控制军团与民众的心理掌控超能力者们发动了一次记忆战争，直接影响了厄尔科斯所有普通民众的记忆。"
    "【翼前辈】\n\_l[35,-]佐羽川 翼，跨维度空间冒险第一人，本宇宙空间断档最强，她一直很执着探索维度外空间，即使她的躯体一点一点地丢失，这里是指username想学翼前辈那样不顾一切。"
    "【ali】\n\_l[35,-]本意是歌唱，又引申为表达自己的情感。"
    "【起点站的名字】\n\_l[35,-]“只有一点不要忘记，起点站的名字”，这里致敬现实中的歌曲“kukui - ゆめわたしの夜”，是akas的挚爱，于是akas编了首管弦乐（水平不高），可以听听：\q[ゆめわたしの夜,OnOpenlink,https://musicoka.oss-cn-guangzhou.aliyuncs.com/tindalia/%E3%82%86%E3%82%81%E3%82%8F%E3%81%9F%E3%82%8A%E3%81%AE%E5%A4%9C.wav]"
    "【飞行之中，不能着陆】\n\_l[35,-]飞行中需要观云测雾，如果顾着鸟瞰大地欣赏美色，就很容易伤到自己。"
    "【消失的四年】\n\_l[35,-]主角们认为，她们没有关于大海难的记忆，大海难持续了四年，也就是一个静寂季的时间，这里就是指静寂季的时间。"
    "【我】\n\_l[35,-]指体验过那些凄美的情绪的username自己，而不是空洞虚无的傀儡。"
    "【飓风之后】\n\_l[35,-]近代花咲季发生了一场万丈飓风，事实是从飓风到大海难之间存在一段时间，对于主角们来说，她们没有这段记忆，飓风之后就是升学住院的记忆了。"
    "【紫癫】\n\_l[35,-]2040年末旬出现的一种疾病，于2041年上旬患病人数增多，病理是患者体内电粒子失控冲击大脑引发癫痫、瘫痪。"
    "【飓风之中】\n\_l[35,-]指username与约死群的姐妹们奔赴万丈飓风赴死的事情，在飓风中，不缺少有主动献祭的消逝一族。"
    "【森林中那些魔法阵】\n\_l[35,-]这里指的是alia主动献祭的魔法阵。"
    "【suai】\n\_l[35,-]单词原意是闪耀、闪光，后引申为用尽所有力气将最美丽的事物炫耀出来，在厄尔科斯中，通常是指用生命将心中那些沸腾的情绪表达出来。"
    "【空间构造学】\n\_l[35,-]厄尔科斯的一门学科，研究方向是宇宙介质空间中的各种规律，小到生成细胞的空间粒子，大到境界之间的宇宙片区。"
    "【境界语言学】\n\_l[35,-]已探知的宇宙中有若干个文明，每个相似的文明共同组成一个境界，每个境界之间的人类都有相似的发声器官，所以一个境界的语言有规律可寻，就衍生出了境界语言学。"
    "【格罗兹尼介质】\n\_l[35,-]在厄尔科斯中，发动魔法或者超能力，就是使用介质控制这些漂浮在各处的格罗兹尼介质来实现魔法或超能力的效果。"
    "【树海】\n\_l[35,-]指青木原树海，小说《波之塔》提及此处为自杀地点，在厄尔科斯树海确是代表着诞生的地方，近年来受文化风气影响，树海也变成了自杀圣地。"
    "【天空执行队】\n\_l[35,-]一支巡游于天空的队伍，通常在天空上排成“ヘ”字形，就像飞行的大雁队列，她们的任务是监视地面的群众有没有越过既定规则使用非法的超能力等。"
    "【元世界】\n\_l[35,-]本来的世界，这个词汇如果用在普通人就是存在记忆中白月光般的世界，如果用在异界冒险者就是指厄尔科斯，如果用在超能力者则是指模板世界。"
    "【上层舰队】\n\_l[35,-]厄尔科斯社会阶级已经固化，最底层就是住在地面上的人民，然后就是游走地面与天空的悬空城居民，再上一层就是拥有军事势力的上层舰队。"
    "【辉屑】\n\_l[35,-]光辉的碎屑，空间震把像玻璃一般的天空打碎，碎片像天空的结晶般花瓣一般地落下，这些碎片称为辉屑，是厄尔科斯很常见的一种天象。"
    "【五行大阵】\n\_l[35,-]从前龙族入侵大陆，为了抵御龙族的进攻，大魔法师们在创世诗这个地方前面建起了五行大阵，最终将龙族的活动边界限制在创世诗，也就是今天的降龙坡。"
    "【二姬二路和天陵大道】\n\_l[35,-]愚女坡出入城的主干道，这两条道路很后来才修以前的人一般经虹湖的路，而不是走愚女坡这一边。"
    "祝福】\n\_l[35,-]alia有主动献祭的习俗，每一次献祭都能为世界添上祝福，现代部分alia已经走出森林，慢慢地从主动献祭变成了耗尽全力地祝福。（祝福：全城攻击力+30%，防御力+10%，无视真实伤害……）"
    "【ban】\n\_l[35,-]禁止、禁用或者封禁的意思，这里用在社交平台上是指账号被封禁。"
    "【胆央医】\n\_l[35,-]胆心中央医院的缩写。"
    "【愚女坡精卫】\n\_l[35,-]愚女坡精神卫生中心（愚女坡儿少健康中心）。"
    "【精卫】\n\_l[35,-]精神卫生中心的缩写。"
    --
    "\n\n\![*]\q[返回,outalk]"
}




















//***** keyword↑--------------------------------------------------------------------------------------------------------------------------------------------
//***** 设置、功能↓--------------------------------------------------------------------------------------------------------------------------------------------
//***** 设置*********************************************
Onsettei
{
    if !aoiSeittei ; NaoiSettei
    --
    if !tea ; "\0\s[%(bsus+2)]" ; else ; "\1\s[%(gsus+1)]"
    --
    "\*\_q\![set,autoscroll,disable]\f[name,%(zitai)]"
    --
    "->设置\n\n[half]\f[size,14]/
    \_l[35,-]\![*]\q[修改字体,Qzitai]\_l[135,-]\![*]\q[屏幕亮度,Qlight]\_l[235,-]\![*]\q[路径设置,Qkeilo]\n/
    \_l[25,-]\![*]\q[%(aoiexe),OnOpenfile,%(lediokeilo)]\_l[125,-]\![*]\q[%(nieexe),OnOpenfile,%(fodeiakeilo)]\_l[225,-]\![*]\q[%(saoexe),OnOpenfile,%(saokeilo)]\n/
    \_l[25,-]\![*]\q[今日运势,list]\_l[125,-]\![*]\q[音乐盒,randtitle]\n\n[half]/
    \f[size,default]\_l[60,-]\![*]\q[返回,pamamu]"
}
//————————————————————————————————
//*****字体改变********************
Choice.Qzitai
{
    "\*\0\s[%(bsus+3)]\f[name,%(zitai)]\_q\![*]（点击字体名字可以更换字体）\n\n[half]目前使用的字体是： \q[%(zitai),Onzitaicha,zitai]\n/
    %(username)\f[name,%(mamuzitaiNa)]使用的字体是：\q[%(mamuzitaiNa),Onzitaicha,mamu]\n\n[half]/
    \f[name,%(zitai)]\n\![*]\q[返回,Onsettei]"
}
Onzitaicha
{
    "\*\0\s[%(bsus)]\f[name,%(zitai)]\_q请点击需要变成的字体\n\n\![*]\q[返回,Qzitai]"
    --
    case reference0 {
    when "zitai" { Showzitai("zitai") }
    when "mamu" { Showzitai("mamu") }
    }
}
Showzitai
{
    _t = "\1\s[10]\b[4]\![set,autoscroll,disable]\f[name,%(zitai)]"
    _t += "\_l[68,-]【\f[bold,1]字体\f[bold,0]】\n"
    _fl = fontlist  //1开始 //SPLIT(_fl,"\n")  0开始
    for _i = 1; _i < ARRAYSIZE(_fl)+1; _i++ {
        _t += "\q[%(_fl[_i]),Onchazitai,%(_argv[0]),%(_fl[_i])]\n"
    }
    _t
}
OnNotifyFontInfo
{
    fontlist = IARRAY
    foreach reference ; _t {
        fontlist ,= _t
    }
}
Onchazitai
{
    case reference0 {
    when "zitai" { 
        zitai = reference1
        mamuzitaiNn = zitai
        username =  "\f[name,%(mamuzitaiNa)]%(mamuNuaoi)\f[name,%(mamuzitaiNn)]"
        }
    when "mamu" { 
        mamuzitaiNa = reference1
        username =  "\f[name,%(mamuzitaiNa)]%(mamuNuaoi)\f[name,%(mamuzitaiNn)]"
        }
    }
    Choice.Qzitai
}
//————————————————————————————————
//*****路径改变********************
Choice.Qkeilo
{
    "\*\0\s[%(bsus+2)]\f[name,%(zitai)]\![set,autoscroll,disable]\_q\![*]（点击名字可以更换快捷方式名字，点击路径可更换路径）\n"
    --
    "\q[%(aoiexe),OnQkeiName,1]的路径：\n\q[%(lediokeilo),OnQkeilol,1]\n/
    \q[%(nieexe),OnQkeiName,2]的路径：\n\q[%(fodeiakeilo),OnQkeilol,2]\n/
    \q[%(saoexe),OnQkeiName,3]的路径：\n\q[%(saokeilo),OnQkeilol,3]\n/
    \n\![*]\q[返回,Onsettei]"
    --
    "\e"
}
OnQkeilol
{
    "\0\s[%(bsus)]\f[name,%(zitai)]\_q请输入打开《"
    --
    case reference0 {
        when 1 { daiarogu = 1 ; aoiexe }
        when 2 { daiarogu = 2 ; nieexe }
        when 3 { daiarogu = 3 ; saoexe }
    }
    --
    "》运行程序的绝对路径\![open,dialog,open]\e"
}
OnSystemDialog
{
    case daiarogu {
        when 1 { lediokeilo = reference2 }
        when 2 { fodeiakeilo = reference2 }
        when 3 { saokeilo = reference2 }
    }
    --
    Choice.Qkeilo
}
OnQkeiName
{
    "\0\s[%(bsus+2)]\f[name,%(zitai)]\_q请输入程序《"
    --
    case reference0 {
        when 1 { daiarogu = 1 ; aoiexe }
        when 2 { daiarogu = 2 ; nieexe }
        when 3 { daiarogu = 3 ; saoexe }
    }
    --
    "》的新快捷方式名字：\![open,inputbox,WisQkeiName,-1]"
}
Input.WisQkeiName
{
    "\t\0\s[%(bsus)]\f[name,%(zitai)]"
    --
    if reference1 == ""
    { "\s[%(bsus+3)]抱歉，我听不到，能再说一遍吗？\![open,inputbox,WisQkeiName,-1]"  }
    else
    {
        case daiarogu {
            when 1 { aoiexe = reference1 }
            when 2 { nieexe = reference1 }
            when 3 { saoexe = reference1 }
        }
        --
        Choice.Qkeilo
    }
}
//————————————————————————————————
//*****屏幕亮度********************
Choice.Qlight
{
    "\*\0\s[%(bsus)]\f[name,%(zitai)]\![set,autoscroll,disable]\_q"
    --
    _txt = SAORI('saori\brightness_saori.dll','GETINFO')
    if "当前亮度" !_in_ _txt { "没有检测到显示器" }
    else{ _txt+"\![*]\q[设置亮度,OnQendi,%(SPLIT(SPLIT(_txt,'描述: ')[1],'\n')[0])]" }
    --
    "\n\n\![*]\q[返回,Onsettei]\e"
}
OnQendi
{
    if !endi[0] ; endi[0] = TOINT(SAORI('saori\brightness_saori.dll','GET','1'))
    if !endi[1] ; endi[1] = 10
    if !endi[2] ; endi[2] = 50
    "\*\0\s[%(bsus+2)]\f[name,%(zitai)]\![set,autoscroll,disable]\_q-> %(reference0)：\n/
    \_l[25,-]\q[设置亮度,Onendi,1]：%(endi[0])\n/
    \_l[25,-]\q[设置步长,Onendi,2]：%(endi[1])\n/
    \_l[25,-]\q[设置延迟,Onendi,3]：%(endi[2])\n/
    \![*]\q[确定,Endisubmit]\n/
    \![*]\q[返回,Qlight]\e"
}
BalloonTooltip.Onendi
{ "步数 - 过渡分多少步完成；延迟 - 每步间隔毫秒数" }
Onendi
{ "\0\s[%(bsus)]\f[name,%(zitai)]\_q请输入"
--
    case reference0 {
        when 1 { endiwa = 1 ; "将要设置的亮度（1-100）\![open,inputbox,autsnu,0,0]"}
        when 2 { endiwa = 2 ; "将要设置的\q[步长,Onendimes,？,1]（1-100）\![open,inputbox,autsnu,0,0]"}
        when 3 { endiwa = 3 ; "将要设置的\q[延迟,Onendimes,？,2]（1-1000）\![open,inputbox,autsnu,0,0]"}
    }
}
Input.autsnu
{
    if !ISINTEGER(reference1) && !ISREAL(reference1) { "\![raise,Onendi,%(endiwa)]" ; return ; }
    else {
        case endiwa {
            when 1 { if reference1>0 && reference1<101 ; endi[0] = reference1 ; else { "\![raise,Onendi,%(endiwa)]" ; return ; }}
            when 2 { if reference1>0 && reference1<101 ; endi[1] = reference1 ; else { "\![raise,Onendi,%(endiwa)]" ; return ; }}
            when 3 { if reference1>0 && reference1<1001 ; endi[2] = reference1 ; else { "\![raise,Onendi,%(endiwa)]" ; return ; }}
        }
    }
    OnQendi
}
Choice.Endisubmit
{
    if SAORI("saori\brightness_saori.dll","SET","1","%(endi[0])","smooth","endi[1]","endi[2]") { Choice.Qlight }
    else { "设置失败\n"+Choice.Qlight }
}
Onendimes
{
"\*\0\s[%(bsus)]\f[name,%(zitai)]\![set,autoscroll,disable]\_q"
--
    case reference1 {
        when 1 { "/
            步数 (steps) 的作用：\n/
              将亮度变化分成多个小步骤完成。\n/
              步数越多，过渡越平滑，但耗时越长。\n/
            \n/
            \_l[15,-]推荐值：\n/
            \_l[15,-]- 5-10步：快速变化，适合日常快速调节\n/
            \_l[15,-]- 10-20步：平滑自然，最推荐\n/
            \_l[15,-]- 20-30步：非常平滑，适合演示效果\n/
            \_l[15,-]- 30-50步：缓慢渐变，适合氛围变化\n/
        " }
        when 2 { "/
            延迟 (delay) 的作用：\n/
            \_l[15,-]每一步之间的等待时间（毫秒）。\n/
            \_l[15,-]延迟越长，过渡速度越慢。\n/
            \n/
            \_l[15,-]推荐值：\n/
            \_l[15,-]- 20-30ms：快速过渡\n/
            \_l[15,-]- 30-50ms：速度适中，最推荐\n/
            \_l[15,-]- 50-80ms：缓慢过渡\n/
            \_l[15,-]- 80-100ms：非常缓慢\n/
        " }
    }
}