﻿tia
{
    if month > 2 && month < 6
    {
        if hour > 6 && hour < 17
        { "春天白天" }
        elseif hour > 16 && hour < 19
        { "春天黄昏" }
        else
        { "春天夜晚" }
    }
    elseif month > 5 && month < 9
    {
        if hour > 6 && hour < 17
        { "夏天白天" }
        elseif hour > 16 && hour < 19
        { "夏天黄昏" }
        else
        { "夏天夜晚" }
    }
    elseif month > 8 && month < 12
    {
        if hour > 6 && hour < 17
        { "秋天白天" }
        elseif hour > 16 && hour < 19
        { "秋天黄昏" }
        else
        { "秋天夜晚" }
    }
    else
    {
        if hour > 6 && hour < 17
        { "冬天白天" }
        elseif hour > 16 && hour < 19
        { "冬天黄昏" }
        else
        { "冬天夜晚" }
    }
}



//*************************厄尔科斯时间
sueseo
{ '花咲季    ~hasawa~' }
Choice.elkstia
{   "\![open,dateinput,elkstia,-1,%(year),%(month),%(day)]"   }
Input.elkstia
{
    void reNului(reference1[0],reference1[1],reference1[2])
    marklnb(reference1[0],reference1[1],reference1[2])
}
reNului
{
    if !_argv[0] ; _argv[0] = year ;
    if !_argv[1] ; _argv[1] = month ;
    if !_argv[2] ; _argv[2] = day ;

    if (loihensa = TOINT(_argv[0]-2015))<0 ; loihensa=-loihensa ;
    lnihensa = TOINT(FLOOR(loihensa/4)) ;
    
    if (_argv[0]-2015+1)>0 {
        tlui = TOINT(loihensa*365+lnihensa+TOINT((0,31,59,90,120,151,181,212,243,273,304,334)[_argv[1]-1])+TOINT(_argv[2])-1) ;
        reloi = TOINT(2030+FLOOR(tlui/360)) ;
        relni = TOINT(FLOOR(tlui/30)%12 +1) ;    //月份1-12
        if !(relui = TOINT((tlui+1)%30)) ; relui= 30 ;    //日期1-30
        relniba = TOINT(FLOOR(tlui/30)%7) ;    //月种0-6
        if !(resazr = TOINT(((relui-1)+2*relniba)%7)) ; resazr=7 ;    //星期1-7
    
    }else{
        tlui = TOINT((loihensa-1)*365)+lnihensa+TOINT((365,334,306,275,245,214,184,153,122,92,61,31)[_argv[1]-1]-_argv[2]) ;
        reloi = TOINT(2029-FLOOR(tlui/360)) ;
        relni = TOINT(12-FLOOR(tlui/30)%12) ;    //月份1-12
        relui = TOINT(30-tlui%30) ;    //日期1-30
        relniba = TOINT(6-FLOOR(tlui/30)%7) ;    //月种0-6
        resazr = TOINT(((relui-1)+2*relniba)%7) ;    //星期1-7
    }
    relniba += 1    //月种1-7
    "\![set,autoscroll,disable]\f[name,%(zitai)]/
    ❀%(boottia)❀\_q\n现在的时间是：【%(wisjikan(hour)):%(wisjikan(minute))】\n▲%(sueseo)\n/
    %(reloi)年 %(wisjikan(relni))月 %(wisjikan(relui))日，%(wissazr(resazr))    月种：%(wislniba(relniba))"
    --
    "\n    "+(,,,,,,,,'七实祭',,,,'莉兹季')[relni]
    --
    if ASEARCHEX(relui,wanNelui(relniba)) ; "\n    休息日~"
}
wanNelui
{ case _argv[0] {
when 1 ; (4,7,10,14,16,20,21,22,26,28)
when 2 ; (2,5,8,12,14,18,19,20,24,26,30)
when 3 ; (3,6,10,12,16,17,18,22,24,28)
when 4 ; (1,4,8,10,14,15,16,20,22,26,29)
when 5 ; (2,6,8,12,13,14,18,20,24,27,30)
when 6 ; (4,6,10,11,12,16,18,22,25,28)
when 7 ; (2,4,8,9,10,14,16,20,23,26,30)
}}
wissazr
{ ('星期一 ~foia sazr~','星期二 ~hasa sazr~','星期三 ~kasa sazr~','星期四 ~qinesa sazr~','星期五 ~snLialia sazr~','星期六 ~lisrli sazr~','星期日 ~wanma sazr~')[_argv[0]-1] }
wislniba
{ ('tue','lei','zei','klo','liu','neu','fba')[_argv[0]-1] }
//**** 厄尔科斯月历 ------------------------------------------------------------------
//*********月历
Choice.elkslnb
{
    void reNului(year,month,day)
    marklnb(year,month,day)
}
marklnb
{
    if !_argv[0] ; _argv[0] = year ;
    if !_argv[1] ; _argv[1] = month ;
    if !_argv[2] ; _argv[2] = day ;

_head = "%(_argv[0])%(wisjikan(_argv[1]))%(wisjikan(_argv[2]))"
_resimg = "%(pakeilo)lniba\%(_head).png"
_txt = "\1\b[0]\*\_b[%(_resimg),0,0,opaque]\f[name,%(zitai)]\q[%(reloi)/%(wisjikan(relni))/%(wisjikan(relui)),elkstia]"
//检查是否存在当天日期
foreach FENUM('\lniba')  ; _tmp{ 
    if SPLITPATH(_tmp)[2] == _head {
    _txt
    return
}}



_base = "%(pakeilo)lniba\"
if "春天" _in_ tia ; _base += "haru.png"
elseif "夏天" _in_ tia ; _base += "natsu.png"
elseif "秋天" _in_ tia ; _base += "aki.png"
else ; _base += "fuyu.png"
_lnb = "%(pakeilo)lniba\%(wislniba(relniba))00.png"
_basedib = SAORI('saori/imgctl_saori.dll','ToDIB',_base)    //载入图片
_lnbdib = SAORI('saori/imgctl_saori.dll','ToDIB',_lnb)    //载入图片
_lnbpna = SAORI('saori/imgctl_saori.dll','PNGAtoDIB',_lnb)    //载入png数据
//粘贴背景，开始x，开始y，粘贴大小，粘贴图片，截取x，截取y，方式
void SAORI('saori/imgctl_saori.dll','PasteDIB',_basedib,0,0,229,360,_lnbdib,229,360,"pngalpha",_lnbpna)
//dib结果：_basedib
//清除dib
void SAORI('saori/imgctl_saori.dll','DeleteDIB',_lnbdib)
void SAORI('saori/imgctl_saori.dll','DeleteDIB',_lnbpna)



_aja = "%(pakeilo)lniba\12%(RAND(7)).png"
_ajadib = SAORI('saori/imgctl_saori.dll','ToDIB',_aja)
_ajapna = SAORI('saori/imgctl_saori.dll','PNGAtoDIB',_aja)
//********************作画算法
if ((_xline = TOINT(resazr))==7) ; _xline = TOINT(0)
_yline = TOINT(FLOOR(((relui-1)/7,(relui+1)/7,(relui+3)/7,(relui+5)/7,(relui)/7,(relui+2)/7,(relui+4)/7)[relniba-1]))
_ypng = 103 + _yline*29
_xpng = 13 + _xline*29
//粘贴背景，开始x，开始y，粘贴大小，粘贴图片，截取x，截取y，方式
void SAORI('saori/imgctl_saori.dll','PasteDIB',_basedib,_xpng,_ypng,29,29,_ajadib,29,29,"pngalpha",_ajapna)
void SAORI('saori/imgctl_saori.dll','DIBtoPNG',_resimg,_basedib,0)
//清除dib
void SAORI('saori/imgctl_saori.dll','DeleteDIB',_basedib)
void SAORI('saori/imgctl_saori.dll','DeleteDIB',_ajadib)
void SAORI('saori/imgctl_saori.dll','DeleteDIB',_ajapna)

_txt


}